Accueil Atelier

Entre Nous

Echanges entre utilisateurs d'AppleWorks et groupe de discussion

Atelier

Les trucs et astuces pour mieux utiliser AppleWorks

Télécharger

Mises à jour de ClarisWorks et AppleWorks, logiciels additionnels

Liens

La sélection de liens spécial AppleWorks

AppleWorks Contact !

Recevez gratuitement des informations sur AppleWorks par email

A propos de Ma Pomme...

logiciel :

AppleWorks

version(s) :

5.0 - 6.0

environnement(s) :

feuille de calcul

niveau(x) :

intermédiaire

mis à jour le :

15.12.00


Calculer un cumul d'heures à partir des horaires de travail


Question

À partir d'un planning de travail hebdomadaire, je souhaite :

- en fonction des horaires de travail (heure de début, heure de fin) calculer automatiquement la durée quotidienne de travail sachant que l'heure de fin peut être après minuit ;

- effectuer la somme des durées journalières dans une cellule "Cumul hebdo".

Comment faire ?

Réponse

AppleWorks propose tout un ensemble de fonctions dédiées à la gestion du temps, dont le maniement exige des précautions. Pour construire un tableau de calcul automatique des durées quotidienne et hebdomadaires, vous allez faire appel aux fonctions suivantes : HEURES, MINUTES, SOMME, ENT et FRAC. Les trois dernières fonctions ne sont pas particulièrement dédiées à la gestion du temps.

Commencez par saisir votre tableau dans un document Feuille de calcul (comme dans l'écran ci-dessus), en respectant le format des heures exprimé avec AppleWorks : l'heure et les minutes sont séparées par le caractère ":", sans espace avant ni après. Vous pourrez utiliser un autre séparateur comme "h", mais cela vous compliquerait inutilement l'écriture de vos fonctions. Avant ou après la saisie de vos horaires, sélectionnez les différentes cellules qui contiennent des heures, et choisissez Nombre du menu Format, puis cochez le format d'heures 13:59 et validez. Si les horaires sont correctement tapés, AppleWorks les alignera automatiquement à droite des cellules. C'est une bonne technique pour vérifier du premier coup d'œil si la saisie est valide, condition indispensable au fonctionnement des formules que vous allez créer.

Au moment de la saisie des noms des jours, gagnez du temps en faisant travailler AppleWorks à votre place : tapez "lundi" dans la cellule A2, sélectionnez la zone A2 à A8, déroulez le menu Options et choisissez Remplir spécial.

Par défaut, AppleWorks a su reconnaître votre choix, soit "lundi" comme jour de départ, l'affichage du nom complet du jour, et un incrément de 1 jour à chaque cellule. Validez la fenêtre, et voilà, AppleWorks a automatiquement rempli les cellules suivantes jusqu'à dimanche inclus.

Vous allez maintenant calculer pour chaque jour la durée de travail effectué, grâce aux fonctions HEURES et MINUTES. Pour faciliter les calculs antérieurs de totaux, il sera ici plus facile de convertir les durées en minutes, puis éventuellement de les afficher ensuite en heures.

Note : AppleWorks propose deux fonctions dont l'orthographe diffère seulement d'une lettre, mais dont l'usage est nettement différent : HEURE et HEURES. C'est exclusivement le second que nous utiliserons ici.

Les fonctions HEURES et MINUTES nécessitent normalement comme argument — les arguments sont les données à partir desquelles la fonction va effectuer son opération ; ce peut être une donnée fixe, les références à une cellule, ou encore le résultat d'un calcul ou d'une autre fonction — une date ou une heure exprimée au format numérique. Mais ici, puisque vous avez déjà saisi vos horaires au format des heures reconnu par AppleWorks, on peut directement demander à AppleWorks d'effectuer ses calculs à partir des cellules des horaires.

Comment fonctionnent ces formules ? Elles nécessitent chacune un seul argument, un "moment". On désignera ici "moment" un point dans le temps (avec ou sans date), afin d'éviter la confusion avec le mot "heure". On fournit donc un moment à la fonction HEURES, qui retourne l'heure correspondante ; de la même manière, on fournit un moment à la fonction MINUTES qui retourne les minutes correspondantes. Il suffit alors d'effectuer une simple soustraction entre le moment de départ et le moment de fin, avec chaque fonction, puis de convertir le résultat des heures en minutes pour obtenir un résultat total en minutes.
Pour le lundi, on tapera donc dans la cellule D2 la formule suivante :

=HEURES(C2-B2)*60+MINUTES(C2-B2)

Dans notre exemple, le résultat sera "390" minutes, soit 6h30. À noter que sur les périodes n'excédant pas 24 heures, AppleWorks sait automatiquement prendre en compte les heures au-delà de minuit et fournit un résultat exact. Pour éviter d'avoir à convertir manuellement en heures-minutes la durée exprimée en minutes, vous allez ajouter dans la cellule E2 une nouvelle formule :

=HEURES(C2-B2)&"h"&MINUTES(C2-B2)

Cette formule n'a d'autre objectif d'apporter une lisibilité immédiate en heures-minutes à la durée quotidienne de travail. Elle reprend la même syntaxe que la formule précédente, sauf que cette fois vous ne multipliez pas l'heure par 60, et que vous ajoutez l'indication "h" pour distinguer les heures des minutes.

Notez la syntaxe utilisée : on utilise le signe "&" pour séparer calculs et données fixes. Tout ce qui est saisi entre les guillemets ne sera pas interprété par AppleWorks. Cela vous donne une grande liberté de présentation. En contrepartie, les choix de formats effectués dans Nombre du menu Format ne s'appliquent plus. Dans notre exemple, la cellule E2 affiche désormais "6h30", et votre écran doit être similaire à l'écran ci-dessous.

Il ne reste plus qu'à recopier vos deux formules vers le bas jusqu'à la rangée 8 ? Presque. En effet, on ne travaille pas forcément tous les jours, et certains jours ne contiendront donc pas d'horaires. Pour être certain qu'il ne s'agit pas d'un oubli, on fait figurer dans la colonne Début (colonne B) de ces jours-ci la mention "Repos".

Si vous recopiez les formules vers le bas tel qu'elles sont actuellement, vous obtiendrez une erreur de la part d'AppleWorks, qui faussera ultérieurement le calcul de vos totaux. Pour prendre en compte ce cas de figure, vous allez ajouter une condition d'exécution à vos formules. Si la cellule correspondante de la colonne B n'indique pas "Repos", alors effectuer le calcul normalement ; sinon, ne rien afficher. Pour traduire cela, vous allez encadrer vos deux formules avec la fonction SI, afin que la cellule D2 apparaisse comme suit :

=SI(B2<>"Repos";HEURES(C2-B2)*60+MINUTES(C2-B2);"")

Et la cellule E2 comme suit :

=SI(B2<>"Repos";HEURES(C2-B2)&"h"&MINUTES(C2-B2);"")

Vous pouvez maintenant recopier vos formules vers le bas. Sélectionnez en même temps les cellules D2 et E2 et glissez vos souris jusqu'à la rangée 8. Puis faites Recopier vers le bas du menu Options.

Il ne vous reste plus qu'à totaliser les heures effectuées dans la semaine. Pour obtenir le total en minutes, la formule est très simple. Tapez-la dans la cellule D10 :

=SOMME(D2..D8)

Mais la lisibilité de ce résultat n'est pas extraordinaire, et cela serait plus agréable d'en avoir la traduction en heures-minutes. Ici, à l'inverse des autres formules de la colonne E, vous allez calculer ce résultat à partir de la durée en minutes.

Rien que de très logique ici : il suffit de prendre la somme en minutes, et de la diviser par 60. La partie entière du résultat correspondra aux heures, et la partie décimale correspondra, elle, aux minutes, exprimées en base 10. Il est donc nécessaire de réunir différentes conversions en une seule formule , sans oublier de ne garder que la partie entière de la division pour les heures et que la partie décimale pour les minutes.

Les fonctions ENT et FRAC vont se révéler très utiles. Comment fonctionnent-elles ? Elles nécessitent chacune un seul argument, ici le résultat d'un calcul. La fonction ENT ne conservera que la partie ENTière, et FRAC uniquement la partie FRACtionelle, soit les décimales. Tapez maintenant dans la cellule E10 la formule suivante (attention aux parenthèses) :

=ENT(D10/60)&"h"&(FRAC(D10/60)/100*60)*100

Pour mieux comprendre comment cette formule fonctionne, décomposons-la en plusieurs éléments :

ENT(D10/60) sert à obtenir le nombre d'heures, soit la partie entière de la division du nombre de minutes par 60.

&"h"& sert à afficher la lettre "h" entre les heures et les minutes, comme utilisé précédemment dans d'autres formules.

Enfin, (FRAC(D10/60)/100*60)*100 est un peu plus compliqué, et calcule le nombre de minutes. On part toujours de l'intérieur d'une formule pour l'analyser lorsqu'il y a plusieurs niveaux de parenthèses. Le cœur de la formule est bien sûr D10/60 qui divise le nombre de minutes par 60. Seule la partie décimale nous intéresse pour les minutes, on ajoute donc la fonction FRAC. Mais ce résultat ne suffit pas, car il est exprimé sur une base de 100ème d'heure et non de 60ème d'heure. Une simple règle de trois permet d'effectuer la conversion, avec /100*60.

C'est terminé ? Presque, car comme cette opération s'effectue sur la partie décimale du résultat, il est nécessaire de multiplier le tout par 100 pour afficher réellement les minutes, d'où le *100 final. Notez que d'un strict point de vue mathématique, on peut supprimer le /100 et le *100, qui n'ont été conservés ici que pour faciliter la lecture et la compréhension de cette formule complexe. Votre écran doit maintenant se présenter comme l'écran ci-dessous.

Bien entendu, rien ne vous empêche de continuer plus loin avec AppleWorks.

Vous pouvez par exemple créer plusieurs tableaux successifs dans un même document pour répercuter une activité sur un mois, puis à l'aide d'une formule reprendre le total des heures effectuées pour générer automatiquement une feuille de salaire. Vous pouvez aussi calculer des statistiques, à l'aide des fonctions MOYENNE, MINIMUM et MAXIMUM.


Accueil Atelier


Accueil

Entre Nous

Atelier

Télécharger

Liens

Newsletter

A propos


© 2002 Ma Pomme - reproduction interdite sans l'accord écrit de www.mapomme.com

[1041]